Notas de Aula - MAC 211 - Laboratório de Programação

Aula 19- 17/5/2002

• O material desta aula foi desenvolvido pelo Prof. Marcos Dimas Gubitoso. Obrigado Gubi!

Processamento de Macros

• O processamento de macros, apesar de parecer uma idéia simples, é extremamente útil e é utilizada em diversos programas como editores de texto, interpretadores e compiladores, pré ou pós processamento de dados, formatação de texto e até mesmo na implementação de linguagens simples. Em editores de texto, basicamente serve para reduzir o volume de digitação ou automatizar tarefas.
• No emacs um macro pode ser iniciado comC-x ( e terminado com C-x ).  Para chamá-la use C-x e. É possível editá-la com C-x X-k.  Para dar um nome use M-x  name-last-kbd-macro.
• Um outro tipo de processamento de macros é o do pré-processador de C.  Por ser apenas substituição de texto, existem alguns cuidados que devem ser tomados para que o resultado final seja realmente o esperado.


#define quad(X)  X*X
quad(3)
quad(a+b)

  é expandido como

3*3
a+b*a+b
 

O mais correto seria

#define quad(X) (X)*(X)

mas mesmo assim existem proplemas como quad(d++)
 
 

M4

• O m4 é um processador genérico de macros.  Em particular o cpp se baseia nele.

A entrada é um texto onde se encontram definições, texto comum e macros
que devem ser expandidos. Os caracteres ` e ' são usados para suspender uma expansão.  Comentários começam com #.
 
• Parâmetros são indicados por $número (e.g., $1, $2, $3...), o número de argumentos é $#,

a lista de argumentos é $* ou $@.  A diferença é que em $@ os argumentos não são  expandidos.
• Alguns exemplos


 define(`foo', `Hello world.')
 define(`troca', `$2, $1')
 define(`eu', `Este sou `eu'.')
 foo
 troca(papai,oi)
eu
 

Alguns macros e comandos especiais:
 

• undefine(NOME)
• defn(NOME) - expande para NOME protegido, assim é  possível fazer define(`batiza',defn(define)
• pushdef(NOME,DEF) e popdef(NOME)
• ifdef(NOME, SIM,  NÃO)
• ifelse(STRING 1, STRING 2, IGUAL, DIFERENTE) - com mais  de quatro argumentos e se a comparação for falsa, repete a partir do quarto argumento.
• ifelse(A,B,sim,C,C,agora sim, nunca)
vira
agora sim
• shift - joga o primeiro argumento fora e retorna os outros
• define(`reverse', `ifelse($#, 0, , $#, 1, ``$1'', `reverse(shift($@)), `$1'')')
• traceon(...) e traceoff(...) - para acompanhar a expansão (usado para deupração).
• dnl --- comentários que são enviados para a saída (?)

Configuração Automática (autoconf)

• O autoconf usa o m4 para escrever um script de configuração automática.  Isto é, a saída do autoconf é um programa de configuração que é colocado junto do seu código fonte.

  Seu código fonte deve estar preparado, fazendo testes sobre macros especiais e se adaptando às diversas situações de um modo padronizado.

  Você também precisará do Mafekile.in, um makefile com macros, que será transformado no Makefile final, na hora de compilar.

  O processo é mais ou menos o seguinte:
   
   

  1. Rode autoscan em seus programas fontes.  A saída será o  arquivo configure.scan
  2. Faça ajustes manuais no configure.scan e guarde como configure.in
  3. Rode o autoconf, ele irá gerar o configure e o  config.h.in

  Feito isso, os seus fontes, mais o configure, o Makefile.in e o config.h.in formam o conjunto do programa.

  Na máquina final, rode oconfigure.  Ele fará todos os testes necessários e arrumará o Makefile.in e o config.h.in,
  construindo o Makefile  e o config.h finais.  O config.h essencialmente conterá os macros que devem ser testados pelos seus programas.
   

•  O Gubi construiu uma biblioteca simples para tornar a programação com Xlib mais simples, chamada xwc.

  Para o xwc Makefile.in é o seguinte:

CFLAGS=-Wall -g @CFLAGS@

@XPMTEST@

all : teste teste2 teste3

teste2 : teste2.o xwc.o
        ${CC} ${CFLAGS} -o teste2 teste2.o xwc.o @LDFLAGS@ @LIBS@

ifndef NOXPM
teste3 : teste3.o xwc.o
        ${CC} ${CFLAGS} -o teste3 teste3.o xwc.o @LDFLAGS@ @LIBS@
else
teste3 :
        echo Este programa só funciona com a biblioteca Xpm instalada
endif

teste : teste.o xwc.o
        ${CC} ${CFLAGS} -o teste  teste.o  xwc.o @LDFLAGS@ @LIBS@

xwc.o : xwc.c

clean:
        rm -f *.o teste teste2 teste3 *~ Nose.xpm Tutti.xpm caca

 
 Uma parte do xwc usa a biblioteca Xpm para manipular algumas imagens.  No entanto, mesmo que esta biblioteca não esteja presente, é possível usar o resto das rotinas.  O macro NOXPM indicará se a biblioteca não foi encontrada.  @XPMTEST@ será substituída por uma cadeia vazia ou pela definição de NOXPM, conforme o caso.
 
  O autoscan gerou o seguinte configure.scan:

dnl Process this file with autoconf to produce a configure script.
AC_INIT(teste.c)

dnl Checks for programs.

dnl Checks for libraries.
dnl Replace `main' with a function in -lX11:
AC_CHECK_LIB(X11, main)
dnl Replace `main' with a function in -lXpm:
AC_CHECK_LIB(Xpm, main)
dnl Replace `main' with a function in -lm:
AC_CHECK_LIB(m, main)

dnl Checks for header files.
AC_PATH_X
AC_HEADER_STDC
AC_CHECK_HEADERS(unistd.h)

dnl Checks for typedefs, structures, and compiler characteristics.

dnl Checks for library functions.

AC_OUTPUT(Makefile)

  Mas, para o teste das bibliotecas X funcionarem, os diretórios de include e de bibliotecas já devem estar atualizados.
  Assim, o configure.scan teve de ser editado e sua versão final (configure.in) ficou assim (os comentários do Gubi estão em  português):

dnl -*- mode:m4 -*-
dnl Process this file with autoconf to produce a configure script.
AC_INIT(teste.c)

dnl Checks for programs.

dnl Só para completar
AC_PROG_CC

dnl Checks for libraries.
dnl Precisamos do X, este macro define x_libraries e x_includes, os
dnl diretórios procurados
AC_PATH_X

dnl Ajustando as opções de compilação
LDFLAGS="-L${x_libraries} $LDFLAGS"
CFLAGS="-I${x_includes} $CFLAGS"

dnl Replace `main' with a function in -lX11:
dnl Xflush é uma das funções usadas
AC_CHECK_LIB(X11, XFlush)

dnl Replace `main' with a function in -lXpm:
dnl XpmReadFileToPixmap é outra.  Veja que neste macro as ações são
dnl diferentes do default.
AC_CHECK_LIB(Xpm, XpmReadFileToPixmap,,
echo Não será possível usar as funções da biblioteca Xpm
XPMTEST="NOXPM=1"
CFLAGS="-D NOXPM $CFLAGS"
)

dnl acertamos @XPMTEST@ no Makefile.in
AC_SUBST(XPMTEST)

dnl Replace `main' with a function in -lm:
dnl usamos o cálculo de tangentes, no teste.c
AC_CHECK_LIB(m, tan)

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(unistd.h)

dnl Checks for typedefs, structures, and compiler characteristics.

dnl Checks for library functions.

AC_OUTPUT(Makefile)

• Para maiores informações sobre o autoconf, visite a página de documentação do GNU autoconf.

• O automake é um utilitário usado para gerar vários arquivos Makefile.in em um pacote formado por vários diretórios. S autoconf/autoscan funciona bem se todo o código-fonte está em um único diretório. Mas se o programador deseja organizar o seu código-fonte separando-o em vários diretórios, cada diretório

com o seu próprio Makefile, então ele precisa usar o automake. O automake vai percorrendo todos os diretórios criando os Makefile.in apropriados. No final, ele cria um script configure só que transforma todos os
Makefile.in em todos os diretórios nos respectivos Makefiles. Maiores detalhes podem ser obtidos em http://sources.redhat.com/automake/automake.html ou na página de documentação do GNU automake.